e26e25b566
- Update ports for Alloy, Grafana, Loki, Prometheus, Promtail, Tempo, and Uptime Kuma to new ranges - Add Arrtrix content management commands and subscriptions - Implement Radarr and Sonarr client logic for movie and series management - Add matrix commands for download and subscription management - Add subscription repository with database schema and logic - Update Arrtrix config and example config for content section - Update help text and command processor to include new commands - Update vendor hash for Arrtrix package
67 lines
1.6 KiB
Nix
67 lines
1.6 KiB
Nix
{ pkgs, config, lib, namespace, ... }:
|
|
let
|
|
inherit (builtins) toString;
|
|
inherit (lib) mkEnableOption mkIf optionals;
|
|
|
|
cfg = config.${namespace}.services.observability.prometheus;
|
|
in
|
|
{
|
|
options.${namespace}.services.observability.prometheus = {
|
|
enable = mkEnableOption "enable Prometheus";
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
services.prometheus = {
|
|
enable = true;
|
|
port = 9200;
|
|
extraFlags = optionals config.${namespace}.services.observability.alloy.enable [
|
|
"--web.enable-remote-write-receiver"
|
|
];
|
|
|
|
globalConfig.scrape_interval = "15s";
|
|
|
|
scrapeConfigs = [
|
|
{
|
|
job_name = "prometheus";
|
|
static_configs = [
|
|
{ targets = [ "localhost:9200" ]; }
|
|
];
|
|
}
|
|
|
|
{
|
|
job_name = "node";
|
|
static_configs = [
|
|
{ targets = [ "localhost:${toString config.services.prometheus.exporters.node.port}" ]; }
|
|
];
|
|
}
|
|
]
|
|
++ optionals config.${namespace}.services.observability.alloy.enable [
|
|
{
|
|
job_name = "alloy";
|
|
static_configs = [
|
|
{ targets = [ "localhost:9700" ]; }
|
|
];
|
|
}
|
|
]
|
|
++ optionals config.${namespace}.services.observability.tempo.enable [
|
|
{
|
|
job_name = "tempo";
|
|
static_configs = [
|
|
{ targets = [ "localhost:9600" ]; }
|
|
];
|
|
}
|
|
];
|
|
|
|
exporters = {
|
|
node = {
|
|
enable = true;
|
|
port = 9201;
|
|
enabledCollectors = [ "systemd" ];
|
|
openFirewall = true;
|
|
};
|
|
};
|
|
};
|
|
|
|
networking.firewall.allowedTCPPorts = [ 9200 ];
|
|
};
|
|
}
|