more progress

modules/home/themes/default.nix

@@ -0,0 +1,36 @@
+{ config, lib, pkgs, namespace, ... }:
+let
+  inherit (lib) mkIf mkDefault;
+  inherit (lib.options) mkOption mkEnableOption;
+  inherit (lib.types) nullOr enum;
+
+  cfg = config.${namespace}.themes;
+in {
+  options.${namespace}.themes = {
+    enable = mkEnableOption "Theming (Stylix)";
+
+    theme = mkOption {
+      type = nullOr (enum [ "everforest" "catppuccin-latte" "chalk" ]);
+      default = "everforest";
+      description = "The theme to set the system to";
+      example = "everforest";
+    };
+
+    polarity = mkOption {
+      type = nullOr (enum [ "dark" "light" ]);
+      default = "dark";
+      description = "determine if system is in dark or light mode";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    ${namespace}.theming.enable = true;
+
+    stylix = {
+      base16Scheme = "${pkgs.base16-schemes}/share/themes/${cfg.theme}.yaml";
+      image = ./${cfg.theme}.jpg;
+      polarity = cfg.polarity;
+      targets.qt.platform = mkDefault "kde6";
+    };
+  };
+}